Project #29 - DFRobot - SHT40 - Mk08

/****** Don Luc Electronics © ******
Software Version Information
Project #29 - DFRobot - SHT40 - Mk08
29-08
DL2403Mk04p.ino
DL2403Mk04
1 x DFRobot FireBeetle 2 ESP32-E
1 x Fermion: SHT40 Temperature & Humidity Sensor
1 x 1 x Lithium Ion Battery - 1000mAh
1 x Rocker Switch - SPST
1 x Resistor 10K Ohm
1 x USB 3.1 Cable A to C
*/

// Include the Library Code
// Bluetooth LE keyboard
#include <BleKeyboard.h>
// Fermion: SHT40 Temperature & Humidity Sensor
#include "Adafruit_SHT4x.h"

// Bluetooth LE Keyboard
BleKeyboard bleKeyboard;
String sKeyboard = "";
// Send Size
byte sendSize = 0;

// Fermion: SHT40 Temperature & Humidity Sensor
Adafruit_SHT4x sht4 = Adafruit_SHT4x();
// Temperature
float T;
// Humidity
float H;

// The number of the Rocker Switch pin
int iSwitch = 17;
// Variable for reading the button status
int SwitchState = 0;

// Define LED
int iLED = 2;

// Software Version Information
String sver = "29-08";

void loop() {

  // Fermion: SHT40 Temperature & Humidity Sensor
  isSHT40();

  // Read the state of the Switch value:
  SwitchState = digitalRead(iSwitch);

  // Check if the button is pressed. If it is, the SwitchState is HIGH:
  if (SwitchState == HIGH) {

    // Bluetooth LE Keyboard
    isBluetooth();

  }
  
  // Delay 1 Second
  delay(1000);

}

// Ble Keyboard
// Bluetooth
// isBluetooth
void isBluetooth() {

  // ESP32 BLE Keyboard
  if(bleKeyboard.isConnected()) {

    // Send Size Length
    sendSize = sKeyboard.length();

    // Send Size, charAt
    for(byte i = 0; i < sendSize+1; i++){

       // Write
       bleKeyboard.write(sKeyboard.charAt(i));
       delay(50);
    
    }
    bleKeyboard.write(KEY_RETURN);

  }

}

// Fermion: SHT40 Temperature & Humidity Sensor
// SHT40 Temperature & Humidity
void isSHT40(){

  // Fermion: SHT40 Temperature & Humidity Sensor
  // Sensors Event
  sensors_event_t humidity, temp;
  // Populate temp and humidity objects
  sht4.getEvent(&humidity, &temp);
  // Temperature
  T = temp.temperature;
  // Humidity
  H = humidity.relative_humidity;
  // DFR|Version|Temperature|Humidity|*
  sKeyboard = "DFR|" + sver + "|" + String(T) + "C|" + String(H) + "% rH|*";

}

// Setup
void setup()
{
  
  // Give display time to power on
  delay(100);

  // Bluetooth LE keyboard
  bleKeyboard.begin();

  // Give display time to power on
  delay(100);

  // Fermion: SHT40 Temperature & Humidity Sensor
  sht4.begin();
  // You can have 3 different precisions, higher precision takes longer
  sht4.setPrecision(SHT4X_HIGH_PRECISION);
  // You can have 6 different heater settings
  sht4.setHeater(SHT4X_NO_HEATER);

  // Give display time to power on
  delay(100);
  
  // Initialize the Switch pin as an input
  pinMode(iSwitch, INPUT);
  
  // Initialize digital pin iLED as an output
  pinMode(iLED, OUTPUT);
  // Outputting high, the LED turns on
  digitalWrite(iLED, HIGH);

  // Delay 5 Second
  delay( 5000 );

}